Ceci est une ancienne révision du document !

Table des matières

Malinette BrutBox

Malinette BrutBox

contributeurs: BrutPop, Reso-nance description : Pratiques musicales collectives date: 2014-… (en développement) techniques: électronique magnétisme tags: ateliers fichiers: licence: GNUGPL liens: http://brutpop.blogspot.fr }}}

teensy, puredata, malinette, laser, musique, ergotherapie

Description

Outils pour favoriser la pratique musicale collective, la BrutBox permet une approche intuitive et expérimentale du geste et de sa restitution musicale. Le projet est à destination de tous publics, d'encadrement pédagogique ou social. Basée sur le framework développé pour la Malinette, la Brutbox associe du logiciel et une interface permettant la connexion avec une collection non-exhaustive de capteurs.

Cahier des charges

Janvier 2015 : cahierdescharges-2015-01.pdf

Nom : BrutBox ?
État de l'art : Orgue Sensoriel. Refaire sensiblement la même chose en moins cher, en libre/reproductible, (en moins bien ergonomiquement ?) mais en plus intéressant musicalement. Les capteurs sont distingués pour les animateurs : déclencheurs/variateurs, afin qu'ils s'accaparent le dispositif. Notez la taille des capteurs, les couleurs, la fixation, la connectique en Jack et l'utilisation avec 1 seul handicapé et 1 animateur.
Entrées : kinect, accéleromètre sans fil, neurosky (sans routage), capteur distance, piezo pince, micro, crayon graphite, conductivité corps (genre makey makey), webcam (face tracking, fiducials, …), gros boutons, pavé XY façon kaospad, tapis XY
Minimiser le champs d’intervention à un seul capteur. Possibilités de séries de capteurs identiques (ex:touches).
Interface : patchs musicaux (faible programmation) : Pure Data ou MaxMSP
Sorties : VST, sortie Midi (vers synthétiseur), 3D (Pure Data)
Production : Armada

État de l'art

Orgue Sensoriel

Valise Interactive

OpLab

Prototypes

Pistes initiales
Protototype 0.1 : Espace Gantner 06/03/2015

Prototype 0.2

juin 2015 au LFO : http://piratepad.net/brutbox

Sélection élargie de capteurs (sensibilités, capacités moteurs)
Design des capteurs plus gros, plus lourds, codes couleurs pour faciliter la compréhension et le maniement
Câblages plus longs pour s'installer coinfortablement danss un espace de jeu collectif
Patchs en forme de pièces musicales préconçues pour X capteurs/participants

Capteurs

Brouillon

Externe : Joystick Thrustmaster®
Externe : Wiimote® (mac) » Voir la page ressource Wiimote
Infrarouge 3/30cm : 1 ana
infrarouge 20/150cm : 1 ana
Piezo (plaque) : 1 ana
Pression carré (plaque) : 1 ana
Micro electret : 1 ana
Gros bouton (~buzzer) : 1 ana
Module Joystick : 2 ana (prise dédiée)
Accéléromètre ou gyroscope ? : 2 ana (prise dédiée)
Touch : MPR121 prises dédiées SCL/SDA - entrées digitales 5 & 6 D0/D1
Encodeur potentiomètre (+ robinet ?) : prises dédiées “INTERRUPTION” - entrées digitales 7 & 8 D2/D3

Carte électronique

teensy20-usbx8.ai , teensy pin assignments

Logiciel

To do, questions : https://semestriel.framapad.org/p/malinette0.90

Basé sur la Malinette et Pure Data Extended : malinette_v0.90.zip

Firmware Teensy 2

versions avant 09/06/215
Fichiers : …

Réception des données MIDI à partir de Pure Data

teensy_brutbox.ino (sans on off pour MAC)

/* 
 * TEENSY 2 for BRUTBOX
 * Analog sensors + encoder + touch
 *
 * Licence : GNU/GPL3
 * Date : 12/06/2015
 * Website : http://reso-nance.org/wiki/projets/malinette-brutbox
 *
 * Hardware add-on : the MPR121 module for touch sensors
 *
 * Midi mapping :
 * 12 analog sensors (midi controller from 0 to 11)
 * 1 encoder (midi controller 12)
 * 12 touch sensors (midi note from 60 to 71)
 */
 
 
// Include libraries
#include <Wire.h>
#include "Adafruit_MPR121.h"
#include <Encoder.h>
 
// Midi channel
const int channel = 1;
 
// Analog setup
int anaPins[] = {22,11,12,13,14,15,16,17,18,19,20,21}; // analog pins
const int anaNb = 12; // number of inputs
int anaCtl[] = {11,10,9,8,7,6,5,4,3,2,1,0}; // controller in
int anaValues[anaNb]; // current analog values
int anaLastValues[anaNb]; // previous analog values
 
// Encoder setup
Encoder encoderSensor (7, 8);
long encoderOldPosition  = -999;
long encoderNewPosition;
long encoderLastPosition;
 
// Capacitive Touch MPR121 module
// Connection Teensy2 
// USB wiring : d+ : SDA, d- : SCL, SCL = DO, SDA = D1 
Adafruit_MPR121 cap = Adafruit_MPR121();
uint16_t lasttouched = 0;
uint16_t currtouched = 0;
const int touchNb = 12; // number of touch inputs
int touchCtl[] = {60,61,62,63,64,65,66,67,68,69,70,71}; // note in
 
// Sampling rate
elapsedMillis msec = 0;
 
void setup() { 
  // Trying to connect to the capacitive module
  if (!cap.begin(0x5A)) {
    while (1);
  }
  delay(1000);
} 
 
void loop() {
   if (msec >= 20) {
    msec = 0;
 
      // Analog sensors loop
      for (int i = 0; i < anaNb; i++) {
              anaValues[i] = (int) analogRead(anaPins[i])  / 8 ;
              if (anaValues[i] != anaLastValues[i]) {  
                  usbMIDI.sendControlChange(anaCtl[i], anaValues[i], channel);
                  anaLastValues[i] = anaValues[i];
	      }
       }
 
      // Encoder
       encoderNewPosition = encoderSensor.read();
       if (encoderNewPosition != encoderOldPosition) {
          if (encoderNewPosition > encoderOldPosition) {usbMIDI.sendControlChange(12, 0, channel);} 
          else if (encoderNewPosition < encoderOldPosition) {usbMIDI.sendControlChange(12, 127, channel);}
          encoderOldPosition = encoderNewPosition;
        }        
 
      // Capacitive loop
       currtouched = cap.touched();
       for (uint8_t i=0; i < touchNb; i++) {
            if ((currtouched & _BV(i)) && !(lasttouched & _BV(i)) ) {usbMIDI.sendNoteOn(touchCtl[i], 127, channel);}
            if (!(currtouched & _BV(i)) && (lasttouched & _BV(i)) ) {usbMIDI.sendNoteOn(touchCtl[i], 0, channel);}
       }
       lasttouched = currtouched; // reset our state
  }
 
  while (usbMIDI.read()) {
    // Discard incoming MIDI messages.
  }
}

teensy_brutbox.ino (avec on off)

/* 
 * TEENSY 2 for BRUTBOX
 * Control inputs (sensors) with MIDI messages
 *
 * Licence : GNU/GPL3
 * Date : 11/06/2015
 * Website : http://reso-nance.org/wiki/projets/malinette-brutbox
 *
 * Hardware add-on : the MPR121 module for touch sensors
 *
 * Midi mapping :
 * 12 analog sensors (midi controller from 0 to 11)
 * 1 encoder (midi controller 12)
 * 12 touch sensors (midi note from 60 to 71)
 */
 
 
// Include libraries
#include <Wire.h>
#include "Adafruit_MPR121.h"
#include <Encoder.h>
 
// Midi channel
const int channel = 1;
 
// Capacitive Touch MPR121 module
// Connection Teensy2 
// USB wiring : d+ : SDA, d- : SCL, SCL = DO, SDA = D1 
Adafruit_MPR121 cap = Adafruit_MPR121();
uint16_t lasttouched = 0;
uint16_t currtouched = 0;
const int touchNb = 12; // number of touch inputs
const int touchThreshold = 60;
int touchStateCtl[] = {40, 41, 42} ; // touch on/off
int touchState[touchNb]; // state : on/off
//int currentTouchValues[touchNb]; 
//int lastTouchValues[touchNb];
int touchCtl[] = {60,61,62,63,64,65,66,67,68,69,70,71}; // note in
int touchOn = 0;
 
// Analog setup
int anaPins[] = {22,11,12,13,14,15,16,17,18,19,20,21}; // analog pins
const int anaNb = 12; // number of inputs
int anaCtl[] = {11,10,9,8,7,6,5,4,3,2,1,0}; // controller in
int anaStateCtl[] = {20, 21} ; // sensor on (20), sensor off (21)
int anaState[anaNb]; // state : on/off
int anaValues[anaNb]; // current analog values
int anaLastValues[anaNb]; // previous analog values
 
// Encoder setup
Encoder encoderSensor (7, 8);
long encoderOldPosition  = -999;
long encoderNewPosition;
long encoderLastPosition;
int encoderStateCtl = 13; // receive ctlout 13
int encoderOn = 0;
 
// Sampling rate
elapsedMillis msec = 0;
int rate = 20;
 
void setup() { 
  // Midi receive : on/off sensors 
  usbMIDI.setHandleControlChange(OnControlChange);
} 
 
void loop() {
   if (msec >= rate) {
    msec = 0;
 
      // Analog sensors loop
      for (int i = 0; i < anaNb; i++) {
          if(anaState[i] == 1)  { // check first if the sensor is on
              anaValues[i] = (int) analogRead(anaPins[i])  / 8 ;
              if (anaValues[i] != anaLastValues[i]) {  
                  usbMIDI.sendControlChange(anaCtl[i], anaValues[i], channel);
                  anaLastValues[i] = anaValues[i];
	      }
          }
       }
 
      // Capacitive loop
      if(touchOn == 1){
       currtouched = cap.touched();
       for (uint8_t i=0; i < touchNb; i++) {
         if(touchState[i] == 1)  { // check first if the sensor is on
            if ((currtouched & _BV(i)) && !(lasttouched & _BV(i)) ) {
              usbMIDI.sendNoteOn(touchCtl[i], 127, channel);
            }
            if (!(currtouched & _BV(i)) && (lasttouched & _BV(i)) ) {
              usbMIDI.sendNoteOn(touchCtl[i], 0, channel);
            }
          }
        }
        lasttouched = currtouched; // reset our state
      }
 
     // Encoder
     if (encoderOn == 1) {
       encoderNewPosition = encoderSensor.read();
       if (encoderNewPosition != encoderOldPosition) {
          if (encoderNewPosition > encoderOldPosition) {
            usbMIDI.sendControlChange(12, 0, channel);
          } else if (encoderNewPosition < encoderOldPosition) {
            usbMIDI.sendControlChange(12, 127, channel);
          }
          encoderOldPosition = encoderNewPosition;
          usbMIDI.sendControlChange(12, encoderNewPosition, channel);
        }
     }
  }
 
  while (usbMIDI.read()) {
    // Discard incoming MIDI messages.
  }
}
 
// Receive Midi Control Change
void OnControlChange(byte channel, byte control, byte value) {
   // Analog sensors on/off
   if (control == anaStateCtl[0]) {anaState[-value+(anaNb-1)] = 0;}
   else if (control == anaStateCtl[1]) {anaState[-value+(anaNb-1)] = 1;}
   else if (control == touchStateCtl[0]) {touchState[value] = 0;}
   else if (control == touchStateCtl[1]) {touchState[value] = 1;}
   else if (control == touchStateCtl[2]) {
     touchOn = value;
     if (touchOn == 1) {cap.begin(0x5A);}
   }
   else if (control == encoderStateCtl) {encoderOn = value;}
}

teensy-onoff_no-capacitif.ino (avec on/off et encoder)

// Include libraries
#include <Wire.h>
//#include "Adafruit_MPR121.h"
#include <Encoder.h>
 
// Midi channel
const int channel = 1;
 
// Analog setup
int anaPins[] = {22,11,12,13,14,15,16,17,18,19,20,21}; // analog pins
const int anaNb = 12; // number of inputs
int anaCtl[] = {20,21,22,23,24,25,26,27,28,29,30,31}; // cc non-attribués
int anaStateCtl[] = {20, 21} ; // sensor on (20), sensor off (21)
int anaState[anaNb]; // state : on/off
int anaValues[anaNb]; // current analog values
int anaLastValues[anaNb]; // previous analog values
 
// Encoder setup
Encoder encoderSensor (7, 8);
long encoderOldPosition  = -999;
long encoderNewPosition;
long encoderLastPosition;
int encoderStateCtl = 13; // receive ctlout 13
int encoderOn = 0;
 
// Sampling rate
elapsedMillis msec = 0;
int rate = 20;
 
void setup() { 
  // Midi receive : on/off sensors 
  usbMIDI.setHandleControlChange(OnControlChange);
} 
 
void loop() {
   if (msec >= rate) {
    msec = 0;
 
      // Analog sensors loop
      for (int i = 0; i < anaNb; i++) {
          if(anaState[i] == 1)  { // check first if the sensor is on
              anaValues[i] = (int) analogRead(anaPins[i])  / 8 ;
              if (anaValues[i] != anaLastValues[i]) {  
                  usbMIDI.sendControlChange(anaCtl[i], anaValues[i], channel);
                  anaLastValues[i] = anaValues[i];
	      }
          }
       }
 
 
     // Encoder
     if (encoderOn == 1) {
       encoderNewPosition = encoderSensor.read();
       if (encoderNewPosition != encoderOldPosition) {
          if (encoderNewPosition > encoderOldPosition) {
            usbMIDI.sendControlChange(12, 0, channel);
          } else if (encoderNewPosition < encoderOldPosition) {
            usbMIDI.sendControlChange(12, 127, channel);
          }
          encoderOldPosition = encoderNewPosition;
          usbMIDI.sendControlChange(12, encoderNewPosition, channel);
        }
     }
  }
 
  while (usbMIDI.read()) {
    // Discard incoming MIDI messages.
  }
}
 
// Receive Midi Control Change
void OnControlChange(byte channel, byte control, byte value) {
   // Analog sensors on/off
   if (control == anaStateCtl[0]) {anaState[-value+(anaNb-1)] = 0;}
   else if (control == anaStateCtl[1]) {anaState[-value+(anaNb-1)] = 1;}
   else if (control == encoderStateCtl) {encoderOn = value;}
}

Wiimote brutbox

Une piste d'utiliser la manette Wiimote pour creer un dispositif ou l'on peut changer de capteur. En démontant le nunchuk et en retirant le joystick nous pouvons utiliser deux entrées analogiques. Attention la wiimote est alimenté en 3.3v, donc nous sommes limité aux capteurs resistifs qui fonctionnent à cette tension.

On utilise ensuite OSCULATOR (sur macOS) pour recevoir les données et les transformer en midi. Voir page ressource Wiimote

Wiki

Panneau latéral

Table des matières

Malinette BrutBox

Description

Cahier des charges

État de l'art

Prototypes

Prototype 0.2

Capteurs

Carte électronique

Logiciel

Firmware Teensy 2

Wiimote brutbox

Wiki

Outils pour utilisateurs

Outils du site

Panneau latéral

Table des matières

Malinette BrutBox

Description

Cahier des charges

État de l'art

Prototypes

Prototype 0.2

Capteurs

Carte électronique

Logiciel

Firmware Teensy 2

Wiimote brutbox

Outils de la page